Candlestick Tradingsystem

Eröffnet von ReneRose_alt im Board Handelssysteme mit Equilla

Seitenlänge102030
Seite 1 von 1
#9: 26.11.2009 09:09 Rock
@Rene Rose (#8)

Guten Morgen, Rene

ups, da habe ich tatsächlich vergessen, auf das Datum zu schauen.

Du hast die Idee also nicht mehr weiter verfolgt?

Gruß Rock



The markets can remain irrational longer than you can remain solvent
#8: 26.11.2009 07:59 ReneRose
@Rock (#7)

Guten Morgen!

Ich weiß es auch nicht. Das Material ist von 2004, soweit ich das sehen kann.

--- Sonnige Grüße von Rene Rose---

Aktuelle Seminartermine

rene@renerose.de
#7: 25.11.2009 14:40 Rock
@ReneRose (#1)
Hallo, Rene

den Diskussionsthread, den du dazu angibst, finde ich leider nicht.

Was ergeben denn die Tests des Candle Systems?

Gruß



The markets can remain irrational longer than you can remain solvent
#6: 23.07.2009 14:42 ReneRose
@Gold1 (#4)
...und ja, die zwei Tage sind schon sehr viel Material. Aber wenn Du keinerlei Hintergrund hast, ist der zweite Tag evtl. etwas heftig.

--- Sonnige Grüße von Rene Rose---

Aktuelle Seminartermine

rene@renerose.de
#5: 23.07.2009 14:33 ReneRose
@Gold1 (#4)
1) Sell ist nicht SellShort :)
2) Du musst auch schließende Klammern hinter den Bezeichnungen unterbringen.

--- Sonnige Grüße von Rene Rose---

Aktuelle Seminartermine

rene@renerose.de
#4: 23.07.2009 13:59 Gold1
@Rene Rose (#3)
okay werde ich mir mal überlegen klingt interessant
lernt man das meiste der basis denn in 2 tagen ?

ich habe aktuell ezwas programiert kannst du mir evtl sagen wo der fehler liegt ?

if price > name then buy ("name" next bar at market;
if price < name then sell("name" next bar at market;

if marketpoosition = 1 and price < name then exitlong this bar at market;
if marketposition = -1 and price > name then exitshort this bar at market;

das muesste doch den einstieg (plus gehen generieren ) das stoppen von der plus position und Short gehen und dessen stop

oder übersehe ich da was ?

du siehst ds sind für dich wohl kleinst problemchen
#3: 23.07.2009 12:32 ReneRose
@Gold1 (#2)
...könnte!

Siehe Webseite :)

--- Sonnige Grüße von Rene Rose---

Aktuelle Seminartermine

rene@renerose.de
#2: 23.07.2009 11:43 Gold1
@ReneRose (#1)
Hey Rene Stephan hier sag mal wo kann ich mehr über equilla erfahren
bzw woher nimmst du deine kenntnisse.

bei mir geht es manchmal nicht mit rechten dingen zu

ich generiere ein buy signal gekoppelt mit nem stop level
(was funktioniert)
dann generiere ich auf die gleiche art ein Sell Signal mit einem stop level (welches nicht funktioniert ?!)

kannst du mir evtl helfen ?
#1: 19.02.2004 12:09 ReneRose_alt
Ich möchte hier ein erstes einfaches Candlestick Tradingystem vorstellen. Es ist weder ein sinnvolles MM, noch ein Riskmanagement eingebaut.
Solche Dinge folgen später. Es stehen 30 Muster aus der Candlesticklehre, und der einfache Musterlehre zur Verfügung. Jedes Muster kann einzeln zu und abgeschaltet werden. Als Trendefinition ist ein SMA vorgesehen. Auch das will ich später noch ändern.
Mit dem vorliegenden System lässt sich gut testen, welche Kursmuster profitable Trades versprechen, und welche nicht!
Als Erweiterung ist geplant, vernüftiges Riskikomanagement, vernünftige Gewinnsicherung und ExitStrategie.
Vorerst werden die einzelnen Muster zur Diskussion gestellt. In folgendem Thread könnt Ihr Euch an der Musterverbesserung beteiligen:

http://www.de.tradesignal.com/content.asp?p=cmy/forum/thread.asp&site=1&board=36&thread=12218

es folgen die Codes, die benötigt werden:

meta:    Synopsis ("Candle Pattern "),
        subchart ( false );
        
inputs:    Price ( Close ),
        TrendPeriod ( 5 , 1 ),
        ExitBarCount ( 3 , 1 ),
        Trendfilter ( true ),
        Hammer ( false ),
        HangingMan ( false ),
        BullishEngulfing( false ),
        BearishEngulfing( false ),
        DarkCloudCover ( false ),
        PiercingPattern ( false ),
        MorningStar ( false ),
        EveningStar ( false ),
        HammerInvers ( false ),
        Shootingstar ( false ),
        BullishHarami ( false ),
        BearishHarami ( false ),
        DojiBullish ( false ),
        DojiBearish ( false ),
        HaramiCrossBearish( false ),
        HaramiCrossBullish( false ),
        DragonflyDoji ( false ),
        GravestoneDoji ( false ),
        TweezerTop ( false ),
        TweezerBottom ( false ),
        BullishPitFall ( false ),
        BearishPitFall ( false ),
        BullishSunRise ( false ),
        BearishSunDOwn ( false ),
        BullishKicker ( false ),
        BearishKicker ( false ),
        HammerConfirmed ( false ),
        HangingManConfirmed( false ),
        InvertedHammerConfirmed( false ),
        ShootingStarConfirmed( false ),
        InsideBar ( False ),
        OutsideBar ( false ),
        visuals ( Active , InActive );

Vars:    LongTrend, ShortTrend, TrendVal, Pattern;

Pattern = PatternScanner( 2.0 );

LongTrend = False;
ShortTrend = False;

TrendVal = Average( Price , TrendPeriod );

if Price > TrendVal then LongTrend = true;
if Price < TrendVal then ShortTrend = true;

    
if BarsSinceEntry = ExitBarCount then
    begin
        sell("ExitLong") next bar at market;
        cover("ExitShort") next bar at market;
    end;

        if glob::Pattern1 and Hammer then
            begin
                if Trendfilter and ShortTrend then
                    buy("Hammer") next bar at market
                else
                if Trendfilter = false then
                    buy("Hammer") next bar at market;
            end
        else
        if glob::Pattern2 and HangingMan then
            begin
                if Trendfilter and LongTrend then
                    short("HangingMan") next bar at market
                else
                if Trendfilter = false then
                    short("HangingMan") next bar at market;
            end
        else
        if glob::Pattern3 and BullishEngulfing then
            begin
                if Trendfilter and ShortTrend then
                    buy("BullisgEngulfing") next bar at market
                else
                if Trendfilter = false then
                    buy("BullisgEngulfing") next bar at market;
            end
        else
        if glob::Pattern4 and BearishEngulfing then
            begin
                if Trendfilter and LongTrend then
                    short("BearishEngulfing") next bar at market
                else
                if Trendfilter = false then
                    short("BearishEngulfing") next bar at market;
            end
        else
        if glob::Pattern5 and DarkCloudCover then
            begin
                if Trendfilter and LongTrend then
                    short("DarkCloudCover") next bar at market
                else
                if Trendfilter = false then
                    short("DarkCloudCover") next bar at market
            end
        else
        if glob::Pattern6 and PiercingPattern then
            begin
                if Trendfilter and ShortTrend then
                    buy("PiercingPattern") next bar at market
                else
                if Trendfilter = false then
                    buy("PiercingPattern") next bar at market
            end
        else
        if glob::Pattern7 and MorningStar then
            begin
                if Trendfilter and ShortTrend[1] then
                    buy("MorningStar") next bar at market
                else
                if Trendfilter = false then
                    buy("MorningStar") next bar at market;
            end
        else
        if glob::Pattern8 and EveningStar then
            begin
                if Trendfilter and Longtrend[1] then
                    short("EveningStar") next bar at market
                else
                if Trendfilter = false then
                    short("EveningStar") next bar at market;
            end
        else
        if glob::Pattern9 and HammerInvers then
            begin
                if Trendfilter and ShortTrend then
                    buy("HammerInvers") next bar at market
                else
                if Trendfilter = false then
                    buy("HammerInvers") next bar at market;
            end
        else
        if glob::Pattern10 and ShootingStar then
            begin
                if Trendfilter and Longtrend then
                    short("ShootingStar") next bar at market
                else
                if Trendfilter = false then
                    short("ShootingStar") next bar at market;
            end
        else
        if glob::Pattern11 and BullishHarami then
            begin
                if Trendfilter and ShortTrend then
                    buy("BullishHarami") next bar at market
                else
                if Trendfilter = false then
                    buy("BullishHarami") next bar at market;
            end
        else
        if glob::Pattern12 and BearishHarami then
            begin
                if Trendfilter and Longtrend then
                    short("BearishHarami") next bar at market
                else
                if Trendfilter = false then
                    short("BearishHarami") next bar at market;
            end;
        if glob::Pattern13 and DojiBullish then
            begin
                if Trendfilter and ShortTrend then
                    buy("DojiBullish") next bar at market
            end
        else
        if glob::Pattern13 and DojiBearish then
            begin
                if Trendfilter and LongTrend then
                    short("DojiBearish") next bar at market
            end
        else
        if glob::Pattern14 and HaramiCrossBearish then
            begin
                if Trendfilter and LongTrend then
                    short("HaramiCrossBearish") next bar at market
                else
                if Trendfilter = false then
                    short("HaramiCrossBearish") next bar at market;
            end
        else
        if glob::Pattern15 and HaramiCrossBullish then
            begin
                if Trendfilter and ShortTrend then
                    buy("HaramiCrossBullish") next bar at market
                else
                if Trendfilter = false then
                    buy("HaramiCrossBullish") next bar at market;
            end
        else
        if glob::Pattern16 and DragonflyDoji then
            begin
                if Trendfilter and ShortTrend then
                    buy("DragonflyDoji") next bar at market
                else
                if Trendfilter = false then
                    buy("DragonflyDoji") next bar at market;
            end
        else
        if glob::Pattern17 and GravestoneDoji then
            begin
                if Trendfilter and LongTrend then
                    short("GravestoneDoji") next bar at market
                else
                if Trendfilter = false then
                    short("GravestoneDoji") next bar at market;
            end
        else
        if glob::Pattern18 and TweezerTop then
            begin
                if Trendfilter and LongTrend then
                    short("TweezerTop") next bar at market
                else
                if Trendfilter = false then
                    short("TweezerTop") next bar at market;
            end
        else
        if glob::Pattern19 and TweezerBottom then
            begin
                if Trendfilter and ShortTrend then
                    buy("TweezerBottom") next bar at market
                else
                if Trendfilter = false then
                    buy("TweezerBottom") next bar at market;
            end
        else
        if glob::Pattern20 and BullishPitFall then
            begin
                if Trendfilter and ShortTrend then
                    buy("BullishPitFall") next bar at market
                else
                if Trendfilter = false then
                    buy("BullishPitFall") next bar at market;
            end
        else
        if glob::Pattern21 and BearishPitFall then
            begin
                if Trendfilter and LongTrend then
                    short("BearishPitFall") next bar at market
                else
                if Trendfilter = false then
                    short("BearishPitFall") next bar at market;
            end
        else
        if glob::Pattern22 and BullishSunRise then
            begin
                if Trendfilter and ShortTrend then
                    buy("BullishSunRise") next bar at market
                else
                if Trendfilter = false then
                    buy("BullishSunRise") next bar at market;
            end
        else
        if glob::Pattern23 and BearishSunDown then
            begin
                if Trendfilter and LongTrend then
                    short("BearishSunDown") next bar at market
                else
                if Trendfilter = false then
                    short("BearishSunDown") next bar at market;
            end
        else
        if glob::Pattern24 and BullishKicker then
            begin
                if Trendfilter and ShortTrend then
                    buy("BullishKicker") next bar at market
                else
                if Trendfilter = false then
                    buy("BullishKicker") next bar at market;
            end
        else
        if glob::Pattern25 and BearishKicker then
            begin
                if Trendfilter and LongTrend then
                    short("BearishKicker") next bar at market
                else
                if Trendfilter = false then
                    short("BearishKicker") next bar at market;
            end
        else
        if glob::Pattern26 and HammerConfirmed then
            begin
                if Trendfilter and ShortTrend[1] then
                    buy("HammerConfirmes") next bar at market
                else
                if Trendfilter = false then
                    buy("HammerConfirmes") next bar at market;
            end
        else
        if glob::Pattern27 and HangingManConfirmed then
            begin
                if Trendfilter and LongTrend[1] then
                    short("HangingManConfirmed") next bar at market
                else
                if Trendfilter = false then
                    short("HangingManConfirmed") next bar at market;
            end
        else
        if glob::Pattern28 and InvertedHammerConfirmed then
            begin
                if Trendfilter and ShortTrend[1] then
                    buy("InvertedHammerConfirmed") next bar at market
                else
                if Trendfilter = false then
                    buy("InvertedHammerConfirmed") next bar at market;
            end
        else
        if glob::Pattern29 and ShootingStarConfirmed then
            begin
                if Trendfilter and LongTrend[1] then
                    short("ShootingStarConfirmed") next bar at market
                else
                if Trendfilter = false then
                    short("ShootingStarConfirmed") next bar at market;
            end
        else
        if glob::Pattern30 and InsideBar then
            begin
                if Trendfilter and LongTrend then
                    buy("InsideUp") next bar at market;
            end
        else
        if glob::Pattern30 and InsideBar then
            begin
                if Trendfilter and ShortTrend then
                    short("InsideDown") next bar at market;
            end
        else
        if glob::Pattern31 and OutsideBar then
            begin
                if Trendfilter and LongTrend then
                    buy("OutsideUp") next bar at market;
            end
        else
        if glob::Pattern31 and OutsideBar then
            begin
                if Trendfilter and ShortTrend then
                    short("OutsideDown") next bar at market;
            end;
            
If Visuals = Active then
    DrawLine( Trendval , "Trendline" , Stylesolid , 1 , blue );
[opencode id=508879]

/* CandleStick PatternScanner V1_05 Releasedatum : 07.02.2004 Rene Rose Funktionen benötigt : ClearPattern Wertübergabe : Multiplikator für Ermittlung von Körpergrößen bei z.B. Hammer */
input:    Multiplier( NumericSimple );
        

vars: upshadow, downshadow, candlebody, bodymin, bodymax, Rangemedian, Bodymedian, longbody, whitebody, blackbody, smallbody, gapup, gapdown, windowup, windowdown, maxtoleranz, Dummy;

bodymax = maxlist( close , open );//obere Körperbegrenzung
bodymin = minlist( close , open );//untere Körperbegrenzung
candlebody = bodymax - bodymin;//Körpergröße errechnen
Rangemedian = ( high + low ) * 0.5;//Mittelpunkt der gesamten Range
Bodymedian = ( bodymax + bodymin ) *0.5;//Mitte des Kerzenkörpers
upshadow = high - bodymax;//oberen Schatten errechnen
downshadow = bodymin - low;//unteren Schatten errechnen
longbody = candlebody > Average( candlebody , 5 );//großer Körper
smallbody = candlebody < ( Average( candlebody , 5 ) * 0.75 );//kleiner Körper
whitebody = close > open;//weisse Kerze
blackbody = open > close;//schwarze Kerze
gapup = bodymax[1] < bodymin;//Gap zwischen Körpern, Schatten können sich überlagern
gapdown = bodymin[1] > bodymax;//Gap zwischen den Körpern, Schatten können sich überlagern
windowup = high[1] < low;//window nach Nison
windowdown = low[1] > high;//window nach Nison
maxtoleranz = ( high - low ) * 0.1;//maximaler Toleranzwert beim Vergleichen bestimmter Niveaus

Dummy = ClearPattern;

//hier wird der Hammer definiert--------------------------------------------------------------------------------------------------------------------
if open <> close and bodymin > Rangemedian then//kein Doji , und Längenverhältniss beachten
    begin
        if downshadow > candlebody * Multiplier and upshadow < candlebody then//unterer Schatten muß X * größer als der Körper sein
            glob::Pattern1 = true;
    end;
//hier wird der Hanging Man definiert---------------------------------------------------------------------------------------------------------------
if open <> close and bodymin > Rangemedian then//kein Doji , und Längenverhältniss beachten
    begin
        if downshadow > candlebody * Multiplier and upshadow < candlebody then//unterer Schatten muß X * größer als der Körper sein
            begin
                if bodymin > close[1] and whitebody[1] then//Aufwärtsgap nach weißer Kerze Gestern
                    glob::Pattern2 = true;
            end;
    end;
//hier wird das bullish engulfing Pattern definiert-------------------------------------------------------------------------------------------------
if whitebody and blackbody[1] and open < close[1] and close > open[1] then
    glob::Pattern3 = true;
//hier wird das bearish engulfing Pattern definiert-------------------------------------------------------------------------------------------------
if blackbody and whitebody[1] and open > close[1] and close < open[1] then
    glob::Pattern4 = true;
//hier wird dark cloud cover definiert--------------------------------------------------------------------------------------------------------------
if whitebody[1] and longbody[1] and candlebody[1] > maxlist( upshadow[1] , downshadow[1]) then//große weiße Kerze
    begin
        if open > high[1] and close <= Rangemedian[1] and close > open[1] and longbody then
            glob::Pattern5 = true;
    end;
//hier wird piercing Pattern definiert--------------------------------------------------------------------------------------------------------------
if blackbody[1] and longbody[1] and candlebody[1] > maxlist( upshadow[1] , downshadow[1]) then//große weiße Kerze
    begin
        if open < low[1] and close >= Rangemedian[1] and close < open[1] and longbody then
            glob::Pattern6 = true;
    end;
//hier wird der Morning Star definiert--------------------------------------------------------------------------------------------------------------
if blackbody[2] and maxlist( close[1] , open[1] ) < close[2] and whitebody and close > close[2] and smallbody[1] then//auf ds 2. Gap wird verzichtet
    glob::Pattern7 = true;
//hier wird der Eveningstar definiert----------------------------------------------------------------
if whitebody[2] and minlist( close[1] , open[1] ) > close[2] and blackbody and close < close[2] and smallbody[1] then//auf ds 2. Gap wird verzichtet
    glob::Pattern8 = true;
//hier wird der inverse Hammer definiert------------------------------------------------------------------------------------------------------------
if open <> close and bodymax < Rangemedian and gapdown then//kein Doji , und Längenverhältniss beachten
    begin
        if upshadow > candlebody * Multiplier and downshadow < candlebody then//oberer Schatten muß X * größer als der Körper sein
            glob::Pattern9 = true;
    end;
//hier wird der ShootingStar definiert---------------------------------------------------------------------------------------------------------------
if open <> close and bodymax < Rangemedian and gapup then//kein Doji , und Längenverhältniss beachten
    begin
        if upshadow > candlebody * Multiplier and downshadow < candlebody then//oberer Schatten muß X * größer als der Körper sein
            glob::Pattern10 = true;
    end;
//hier wird das bullish Harami definiert-------------------------------------------------------------------------------------------------------------
if blackbody[1] and longbody[1] then
    begin
        if whitebody and close < open[1] and open > close[1] and smallbody then
            glob::Pattern11 = true;
    end;
//hier wird das bearish Harami definiert-------------------------------------------------------------------------------------------------------------
if whitebody[1] and longbody[1] then
    begin
        if blackbody and open < close[1] and close > open[1] and smallbody then
            glob::Pattern12 = true;
    end;
//hier wird ein Doji definiert-----------------------------------------------------------------------------------------------------------------------
if candlebody <= range * 0.1 then
    begin
        if upshadow > candlebody * 3 and downshadow > candlebody * 3 then
            glob::Pattern13 = true;
    end;
//hier wird ein baerishes Harami Cross definiert-----------------------------------------------------------------------------------------------------
if whitebody[1] and longbody[1] and candlebody <= range * 0.1 then
    begin
        if upshadow > candlebody * 2 and downshadow > candlebody * 2 then
            if bodymax < close[1] and bodymin > open[1] then
            glob::Pattern14 = true;
    end;
//hier wird ein bullishes Harami Cross definiert-----------------------------------------------------------------------------------------------------
if blackbody[1] and longbody[1] and candlebody <= range * 0.1 then
    begin
        if upshadow > candlebody * 2 and downshadow > candlebody * 2 then
            if bodymax < open[1] and bodymin > close[1] then
            glob::Pattern15 = true;
    end;
//hier wird der DragonFly Doji definiert--------------------------------------------------------------------------------------------------------------
if downshadow > ( 2 * candlebody ) and upshadow < ( 0.25 * candlebody ) and candlebody < ( range * 0.1 ) then
    glob::Pattern16 = true;
//hier wird der Gravestone Doji definiert-------------------------------------------------------------------------------------------------------------
if upshadow > ( 2 * candlebody ) and downshadow < ( 0.25 * candlebody ) and candlebody < ( range * 0.1 ) then
    glob::Pattern17 = true;
//hier wird ein Tweezer Top definiert-----------------------------------------------------------------------------------------------------------------
if high[1] = highest( high , 5 )[1] then
    begin
if high = high[1] then glob::Pattern18 = true;
if high >= high[1] and high <= high[1] + maxtoleranz[1] then
    glob::Pattern18 = true;
if high <= high[1] and high >= high[1] - maxtoleranz[1] then
    glob::Pattern18 = true;
    end;
//hier wird ein Tweezer Bottom definiert-----------------------------------------------------------------------------------------------------------------
if low[1] = lowest( low , 5 )[1] then
    begin
if low = low[1] then glob::Pattern19 = true;
if low >= low[1] and low <= low[1] + maxtoleranz[1] then
    glob::Pattern19 = true;
if low <= low[1] and low >= low[1] - maxtoleranz[1] then
    glob::Pattern19 = true;
    end;
// hier wird bullish Pitfall definiert-------------------------------------------------------------------------------------------------------------------
if blackbody[1] and whitebody and gapup and candlebody[1] >= ( Average( candlebody , 5 ) * 0.75 )[2] then
    glob::Pattern20 = true;
//hier wird berish Pitfall definiert---------------------------------------------------------------------------------------------------------------------
if whitebody[1] and blackbody and gapdown and candlebody[1] >= ( Average( candlebody , 5 ) * 0.75 )[2] then
    glob::Pattern21 = true;
//hier wird bullish Sunrise definiert--------------------------------------------------------------------------------------------------------------------
if blackbody[1] and whitebody and open > Bodymedian[1] and gapup = false and close > high[1] then
    glob::Pattern22 = true;
//hier wird bearish Sundown definiert--------------------------------------------------------------------------------------------------------------------
if whitebody[1] and blackbody and open < Bodymedian[1] and gapdown = false and close < low[1]then
    glob::Pattern23 = true;
//hier wird bullish Kicker (counter Attack) definiert----------------------------------------------------------------------------------------------------
if blackbody[1] and whitebody and open < ( low[1] - ( range[1] * 0.5 )) then
    begin
        if close < ( close[1] + maxtoleranz[1] ) and close > ( close[1] - maxtoleranz[1] ) then
            glob::Pattern24 = true;
    end;
//hier wird bearish Kicker (counter Attack) definiert----------------------------------------------------------------------------------------------------
if whitebody[1] and blackbody and open > ( high[1] + ( range[1] * 0.5 )) then
    begin
        if close < ( close[1] + maxtoleranz[1] ) and close > ( close[1] - maxtoleranz[1] ) then
            glob::Pattern25 = true;
    end;
//es folgen einige "confirmed" Muster, also einfache Muster mit Bestätigungskerze------------------------------------------------------------------------
//hier der bestätigte Hammer-----------------------------------------------------------------------------------------------------------------------------
if open[1] <> close[1] and bodymin[1] > Rangemedian[1] then//kein Doji , und Längenverhältniss beachten
    begin
        if downshadow[1] > candlebody[1] * Multiplier[1] and upshadow[1] < candlebody[1] then//unterer Schatten muß X * größer als der Körper sein
            if whitebody and close > close[1] then
                glob::Pattern26 = true;
    end;
//hier der bestätigte Hanging Man------------------------------------------------------------------------------------------------------------------------
if open[1] <> close[1] and bodymin[1] > Rangemedian[1] then//kein Doji , und Längenverhältniss beachten
    begin
        if downshadow[1] > candlebody[1] * Multiplier[1] and upshadow[1] < candlebody[1] then//unterer Schatten muß X * größer als der Körper sein
            begin
                if bodymin[1] > close[2] and whitebody[2] then//Aufwärtsgap nach weißer Kerze Gestern
                    if close < close[1] then
                        glob::Pattern27 = true;
            end;
    end;
//hier der bestätigte inverted Hammer---------------------------------------------------------------------------------------------------------------------
if open[1] <> close[1] and bodymax[1] < Rangemedian[1] and gapdown[1] then//kein Doji , und Längenverhältniss beachten
    begin
        if upshadow[1] > candlebody[1] * Multiplier[1] and downshadow[1] < candlebody[1] then//oberer Schatten muß X * größer als der Körper sein
            if whitebody and close > close[1] then
                glob::Pattern28 = true;
    end;
//hier der bestätigte ShootingStar------------------------------------------------------------------------------------------------------------------------
if open[1] <> close[1] and bodymax[1] < Rangemedian[1] and gapup[1] then//kein Doji , und Längenverhältniss beachten
    begin
        if upshadow[1] > candlebody[1] * Multiplier[1] and downshadow[1] < candlebody[1] then//oberer Schatten muß X * größer als der Körper sein
            if close < close[1] then
                glob::Pattern29 = true;
    end;
//hier wird ein Indisde Bar definiert----------------------------------------------------------------------------------------------------------------------
if high < high[1] and low > low[1] then
    glob::Pattern30 = true;
//hier wird ein Outside Bar definiert----------------------------------------------------------------------------------------------------------------------
if high > high[1] and low < low[1] then
    glob::Pattern31 = true;
PatternScanner = 0;
[opencode id=508880]

/* ClearPattern setzt die globalen Variablen des PatternScanners auf Null Releasedatum : 07.02.2004 Rene Rose */
glob::Pattern1 = false;
glob::Pattern2 = false;
glob::Pattern3 = false;
glob::Pattern4 = false;
glob::Pattern5 = false;
glob::Pattern6 = false;
glob::Pattern7 = false;
glob::Pattern8 = false;
glob::Pattern9 = false;
glob::Pattern10 = false;
glob::Pattern11 = false;
glob::Pattern12 = false;
glob::Pattern13 = false;
glob::Pattern14 = false;
glob::Pattern15 = false;
glob::Pattern16 = false;
glob::Pattern17 = false;
glob::Pattern18 = false;
glob::Pattern19 = false;
glob::Pattern20 = false;
glob::Pattern21 = false;
glob::Pattern22 = false;
glob::Pattern23 = false;
glob::Pattern24 = false;
glob::Pattern25 = false;
glob::Pattern26 = false;
glob::Pattern27 = false;
glob::Pattern28 = false;
glob::Pattern29 = false;
glob::Pattern30 = false;
glob::Pattern31 = false;
ClearPattern = 0;
[opencode id=508881]

ein Beispiel:



Die Trendkomponente kann ebenfals abgeschaltet werden!

Gruß Rene